استخراج فایل فلش از داخل فایل اکسل

گاهی اوقات یک فایل اکسل که محتوی یک فایل فلش هست رو می بینید و دوست دارید فایل فلش داخل اون رو جداگانه داشته باشید، برای این منظور قدم به قدم نحوه ی انجام این کار رو در زیر شرح می دهم (برای بزرگنمایی هر یک از عکس ها رو ی آنها کلیک کنید):

ابتدا من یه فایل اکسل رو که حاوی یه فایل فلش هست رو برای نمونه قرار میدم.

دریافت فایل اکسل حاوی فایل فلش

در اولین قدم برنامه اکسل را باز کنید،

بعد از آن باید برید به قسمت ویرایشگر ویژوآل بیسیک برای اینکار می توانید از منوی Tools گزینه macro بر روی visual basic Editor کلیک کنید.
(برای راحتی کار می توانید از شورتکات آن هم استفاده کنید یعنی Alt+F11)

خوب حالا پنجره ویرایشگر باز شد ، اینجا با توجه به شکل بر روی دکمه view code کنید. (مثل تصویر زیر)

حالا باید کدهای زیر رو در قسمت ویرایشگری که باز شده و در عکس نشان دادم کپی کنید.

کد:

Sub ExtractFlash()

Dim tmpFileName As String
Dim FileNumber As Integer
Dim myFileId As Long
Dim MyFileLen As Long
Dim myIndex As Long
Dim swfFileLen As Long
Dim i As Long
Dim swfArr() As Byte
Dim myArr() As Byte

tmpFileName = Application.GetOpenFilename("MS Office File (*.doc;*.xls), *.doc;*.xls", , "Open MS Office file")

If tmpFileName = "False" Then Exit Sub

myFileId = FreeFile

Open tmpFileName For Binary As #myFileId

MyFileLen = LOF(myFileId)

ReDim myArr(MyFileLen - 1)

Get myFileId, , myArr()

Close myFileId

Application.ScreenUpdating = False

i = 0

Do While i < MyFileLen

   If myArr(i) = &H46 Then

      If myArr(i + 1) = &H57 And myArr(i + 2) = &H53 Then

         swfFileLen = CLng(&H1000000) * myArr(i + 7) + CLng(&H10000) * myArr(i + 6) + CLng(&H100) * myArr(i + 5) + myArr(i + 4)

         ReDim swfArr(swfFileLen - 1)

         For myIndex = 0 To swfFileLen - 1
            swfArr(myIndex) = myArr(i + myIndex)
            Next myIndex
         Exit Do

      Else
            i = i + 3
      End If

   Else
        i = i + 1
   End If

Loop

myFileId = FreeFile

tmpFileName = Left(tmpFileName, Len(tmpFileName) - 4) & ".swf"

Open tmpFileName For Binary As #myFileId

Put #myFileId, , swfArr

Close myFileId

MsgBox "Save the extracted SWF Flash as [ " & tmpFileName & " ]"

End Sub

حالا این کدها رو در قسمت مربوطه paste کنید. (مثل تصویر زیر)

خوب حالا وقت اجرای کدمون می رسه یا بر روی دکمه Run Sub که به شکل یک مثلث کوچولوی سبز رنگ است  کلیک کنید (یا دکمه ی F5 را بفشارید).

همین که کد رو اجرا کنید یک open file dialog باز می شه که (پنجره ی باز کردن فایل) باید آدرس فایل اکسل مورد نظرتون رو که فایل فلش داخلش هست را باز می کنید.

به محض باز کردن فایل یک پیام ظاهر می شه که فایل فلش شما بر روی دسکتاپتان ذخیره شد. (تصویر زیر)